www.ClickEXE.de Click.EXE - In 5 Minuten zum eigenen Programm!
cX5 Zahnräder Jetzt neu: click.EXE 5.0 - Hier klicken für weitere Informationen cX5 Zahnräder
Start Einloggen Einloggen Die Mitglieder Das Foren-Team Suchfunktion
30889 Posts & 5499 Themen in 34 Foren
Benutzername/Passwort:
  Login speichern
Forenübersicht » Andere Versionen und Sprachen » Click.EXE und VB-Script » GUID einbinden

vorheriges Thema   nächstes Thema
5 Posts in diesem Thema (offen)
Seiten (1): (1)
Autor
Beitrag
michi ist offline michi  
Themenicon    GUID einbinden
20 Beiträge - Click.EXE Anfänger
michi`s alternatives Ego
Hallo zusammen
Kann mir jemand helfen beim einbinden eines VB-Skripts? Das Skript soll eine GUID erzeugen..

Hier das Skript:

Private Type GUID
Bytes(0 To 15) As Byte
End Type

Private Type Longs
l1 As Long
l2 As Long
l3 As Long
l4 As Long
End Type

Private Declare Function CoCreateGuid Lib \"OLE32.dll\" _
(tGuid As GUID) As Long
Private Declare Sub CopyMemory Lib \"kernel32\" _
Alias \"RtlMoveMemory\" (VarDest As Any, VarSource As Any, _
ByVal BytesToCopy As Long)
Private Declare Function StringFromGUID2 Lib \"OLE32.dll\" _
(tGuid As GUID, ByVal lpszString As String, ByVal lMax As Long) _
As Long

Public Function CreateGUIDStr() As String
Dim nTemp As String
Dim nGUID As GUID
Dim nLength As Long

nTemp = Space$(78)
CoCreateGuid nGUID
nLength = StringFromGUID2(nGUID, nTemp, Len(nTemp))
CreateGUIDStr = Left$(StrConv(nTemp, vbFromUnicode), nLength - 1)
End Function

Public Function CreateGUIDBytes() As Byte()
Dim nGUID As GUID

CoCreateGuid nGUID
CreateGUIDBytes = nGUID.Bytes
End Function

Public Function GUIDBytesToGUIDStr(GUIDBytes() As Byte) As String
Dim nTemp As String
Dim nGUID As GUID
Dim nLength As Long

nTemp = Space$(78)
CopyMemory nGUID.Bytes(0), GUIDBytes(0), 16
nLength = StringFromGUID2(nGUID, nTemp, Len(nTemp))
GUIDBytesToGUIDStr = Left$(StrConv(nTemp, vbFromUnicode), _
nLength - 1)
End Function

Public Sub GUIDBytesToLongs(GUIDBytes() As Byte, Long1 As Long, _
Long2 As Long, Long3 As Long, Long4 As Long)

Dim nLongs As Longs
Dim nGUID As GUID

CopyMemory nGUID.Bytes(0), GUIDBytes(0), 16
LSet nLongs = nGUID
With nLongs
Long1 = .l1
Long2 = .l2
Long3 = .l3
Long4 = .l4
End With
End Sub

Public Function LongsToGUIDBytes(ByVal Long1 As Long, _
ByVal Long2 As Long, ByVal Long3 As Long, ByVal Long4 As Long) _
As Byte()

Dim nLongs As Longs
Dim nGUID As GUID

With nLongs
.l1 = Long1
.l2 = Long2
.l3 = Long3
.l4 = Long4
End With
LSet nGUID = nLongs
LongsToGUIDBytes = nGUID.Bytes
End Function


Quelle: http://www.aboutvb.de/khw/artikel/khwcreateguid.htm

Danke im voraus
Beitrag vom 22.08.2004 - 01:11
Diesen Beitrag melden   nach weiteren Posts von michi suchen michi`s Profil ansehen michi eine Kurznachricht senden michi zu deinen Freunden hinzufügen zum Anfang der Seite
Gast Plan B  
Gast
Ich kann Deine Frage so auf die Schnelle leider nicht beantworten, habe allerdings bemerkt, dass Du einer Verwechslung aufgesessen bist:
Deine Quelle (siehe Link) bezieht sich nicht auf VB-Skript, sondern auf das "ausgewachsene" Visual Basic. Daher wird es nicht so ohne weiteres gelingen, den Code als externe Funktion in cX zu nutzen. heulend
Beitrag vom 22.08.2004 - 18:20
Diesen Beitrag melden   zum Anfang der Seite
michi ist offline michi  
Themenicon    andere Möglichkeit?
20 Beiträge - Click.EXE Anfänger
michi`s alternatives Ego
Weiss jemand wie man eine solche GUID erstellt? Oder wo man so ein Skript zum einbinden findet?

habe leider bis jetzt noch nichts gefunden...heulend
Beitrag vom 23.08.2004 - 21:53
Diesen Beitrag melden   nach weiteren Posts von michi suchen michi`s Profil ansehen michi eine Kurznachricht senden michi zu deinen Freunden hinzufügen zum Anfang der Seite
Tobi2006 ist offline Tobi2006  
RE: andere Möglichkeit?
4 Beiträge - 2-Tasten-am-Tag-Tipper
Hi michi

Ich versteh nicht was du genau willst aber in VBS kann man die nummer so erzeugen.

Set TypeLib = CreateObject("Scriptlet.TypeLib")
GUID = TypeLib.Guid
Msgbox GUID

Gruess Tobi
Beitrag vom 13.08.2006 - 16:27
Diesen Beitrag melden   nach weiteren Posts von Tobi2006 suchen Tobi2006`s Profil ansehen Tobi2006 eine E-Mail senden Tobi2006 eine Kurznachricht senden Tobi2006 zu deinen Freunden hinzufügen zum Anfang der Seite
michi ist offline michi  
20 Beiträge - Click.EXE Anfänger
michi`s alternatives Ego
Super, danke dir!
Beitrag vom 13.08.2006 - 16:32
Diesen Beitrag melden   nach weiteren Posts von michi suchen michi`s Profil ansehen michi eine Kurznachricht senden michi zu deinen Freunden hinzufügen zum Anfang der Seite
Baumstruktur - Signaturen anzeigen
Seiten (1): (1)
vorheriges Thema   nächstes Thema

Gehe zu:  
Es ist / sind gerade keine registrierte(r) Benutzer und 244 Gäste online. Neuester Benutzer: Volker58
Alles gute zum Geburtstag    Wir gratulieren ganz herzlich zum Geburtstag:
dsoxygen (39), herby471 (68)
aktive Themen der letzten 48 Stunden - Top-User
0
0

www.ClickEXE.de © 2021
Seite in 0.32639 sec generiert